rekahsoft
/
guix
1
1
Fork 0
Code Issues Pull Requests Releases Wiki Activity

build: Add the Android NDK build-system. 

* guix/build-system/android-ndk.scm: New file.
* guix/build/android-ndk-build-system.scm: New file.
* Makefile.am: Add them.
This commit is contained in:
Danny Milosavljevic 2018-04-26 02:15:56 +02:00
parent 74c0ee66bb
commit 436515cdb8
No known key found for this signature in database
GPG Key ID: E71A35542C30BAA5
3 changed files with 214 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

2
Makefile.am
View File

@ -96,6 +96,7 @@ MODULES = \
guix/workers.scm \
guix/zlib.scm \
guix/build-system.scm \
guix/build-system/android-ndk.scm \
guix/build-system/ant.scm \
guix/build-system/cargo.scm \
guix/build-system/cmake.scm \
@ -128,6 +129,7 @@ MODULES = \
guix/svn-download.scm \
guix/i18n.scm \
guix/ui.scm \
guix/build/android-ndk-build-system.scm \
guix/build/ant-build-system.scm \
guix/build/download.scm \
guix/build/download-nar.scm \

126
guix/build-system/android-ndk.scm Normal file
View File

@ -0,0 +1,126 @@
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2016 Danny Milosavljevic <dannym@scratchpost.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (guix build-system android-ndk)
#:use-module (guix search-paths)
#:use-module (guix store)
#:use-module (guix utils)
#:use-module (guix derivations)
#:use-module (guix packages)
#:use-module (guix build-system)
#:use-module (guix build-system gnu)
#:use-module (ice-9 match)
#:use-module (srfi srfi-26)
#:export (android-ndk-build-system))
(define %android-ndk-build-system-modules
;; Build-side modules imported by default.
`((guix build android-ndk-build-system)
(guix build syscalls)
,@%gnu-build-system-modules))
(define* (android-ndk-build store name inputs
#:key
(tests? #t)
(test-target #f)
(phases '(@ (guix build android-ndk-build-system)
%standard-phases))
(outputs '("out"))
(make-flags ''())
(search-paths '())
(system (%current-system))
(guile #f)
(imported-modules %android-ndk-build-system-modules)
(modules '((guix build android-ndk-build-system)
(guix build utils))))
"Build SOURCE using Android NDK, and with INPUTS."
(define builder
`(begin
(use-modules ,@modules)
(android-ndk-build #:name ,name
#:source ,(match (assoc-ref inputs "source")
(((? derivation? source))
(derivation->output-path source))
((source)
source)
(source
source))
#:system ,system
#:test-target ,test-target
#:tests? ,tests?
#:phases ,phases
#:make-flags (cons* "-f"
,(string-append
(derivation->output-path
(car (assoc-ref inputs "android-make-stub")))
"/share/android-make-stub/Makefile")
,make-flags)
#:outputs %outputs
#:search-paths ',(map search-path-specification->sexp
search-paths)
#:inputs %build-inputs)))
(define guile-for-build
(match guile
((? package?)
(package-derivation store guile system #:graft? #f))
(#f ; the default
(let* ((distro (resolve-interface '(gnu packages commencement)))
(guile (module-ref distro 'guile-final)))
(package-derivation store guile system #:graft? #f)))))
(build-expression->derivation store name builder
#:inputs inputs
#:system system
#:modules imported-modules
#:outputs outputs
#:guile-for-build guile-for-build))
(define* (lower name
#:key source inputs native-inputs outputs system target
#:allow-other-keys
#:rest arguments)
"Return a bag for NAME."
(define private-keywords
'(#:source #:target #:inputs #:native-inputs #:outputs))
(and (not target) ;; TODO: support cross-compilation
(bag
(name name)
(system system)
(target target)
(host-inputs `(,@(if source
`(("source" ,source))
'())
,@inputs
;; Keep the standard inputs of 'gnu-build-system'
,@(standard-packages)))
(build-inputs `(("android-make-stub" ,(module-ref (resolve-interface '(gnu packages android)) 'android-make-stub))
,@native-inputs))
(outputs outputs)
(build android-ndk-build)
(arguments (strip-keyword-arguments private-keywords arguments)))))
(define android-ndk-build-system
(build-system
(name 'android-ndk)
(description
"Android NDK build system, to build Android NDK packages")
(lower lower)))

86
guix/build/android-ndk-build-system.scm Normal file
View File

@ -0,0 +1,86 @@
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2018 Danny Milosavljevic <dannym@scratchpost.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (guix build android-ndk-build-system)
#:use-module ((guix build gnu-build-system) #:prefix gnu:)
#:use-module (guix build syscalls)
#:use-module (guix build utils)
#:use-module (ice-9 popen)
#:use-module (ice-9 rdelim)
#:use-module (ice-9 ftw)
#:use-module (ice-9 format)
#:use-module (ice-9 match)
#:use-module (rnrs io ports)
#:use-module (srfi srfi-1)
#:use-module (srfi srfi-26)
#:export (%standard-phases
android-ndk-build))
;; Commentary:
;;
;; Builder-side code of the Android NDK build system.
;;
;; Code:
(define* (configure #:key inputs outputs #:allow-other-keys)
(let ((library-directories (filter-map (match-lambda
((name . path)
(if (eq? 'directory (stat:type (stat path)))
path
#f)))
inputs)))
(setenv "CC" "gcc")
(setenv "CXX" "g++")
(setenv "CPPFLAGS"
(string-join
(map (cut string-append "-I " <> "/include") library-directories)
" "))
(setenv "LDFLAGS"
(string-append "-L . "
(string-join
(map (lambda (x)
(string-append "-L " x "/lib" " -Wl,-rpath=" x "/lib"))
library-directories)
" ")))
#t))
(define* (install #:key inputs outputs (make-flags '()) #:allow-other-keys)
(let ((out (assoc-ref outputs "out")))
(apply invoke "make" "install"
(string-append "prefix=" out)
make-flags)
(if (file-exists? "include")
(copy-recursively "include" (string-append out "/include")))
#t))
(define* (check #:key inputs outputs tests? (make-flags '()) #:allow-other-keys)
;; TODO: Also handle root-level tests.
(when (and (file-exists? "tests") tests?)
(with-directory-excursion "tests"
(apply invoke "make" "check" make-flags))))
(define %standard-phases
(modify-phases gnu:%standard-phases
(replace 'configure configure)
(replace 'install install)
(replace 'check check)))
(define* (android-ndk-build #:key inputs (phases %standard-phases)
#:allow-other-keys #:rest args)
"Build the given Android NDK package, applying all of PHASES in order."
(apply gnu:gnu-build #:inputs inputs #:phases phases args))