a9edb211e7
Before that '.log' files for scheme tests were fragmented and not included in test-suite.log. This unifies the semantics of SRFI-64 API with Automake test suite. * build-aux/test-driver.scm: New file. * Makefile.am (SCM_LOG_DRIVER, AM_SCM_LOG_DRIVER_FLAGS): New variables. (SCM_LOG_COMPILER, AM_SCM_LOG_FLAGS): Delete variables. (AM_TESTS_ENVIRONMENT): Set GUILE_AUTO_COMPILE to 0. * test-env.in: Silence guix-daemon. * doc/guix.texi (Running the Test Suite): Describe how to display the detailed results. Bug reports require only 'test-suite.log' file. * tests/base32.scm, tests/build-utils.scm, tests/builders.scm, tests/challenge.scm, tests/cpan.scm, tests/cpio.scm, tests/cran.scm, tests/cve.scm, tests/derivations.scm, tests/elpa.scm, tests/file-systems.scm, tests/gem.scm, tests/gexp.scm, tests/gnu-maintenance.scm, tests/grafts.scm, tests/graph.scm, tests/gremlin.scm, tests/hackage.scm, tests/hash.scm, tests/import-utils.scm, tests/lint.scm, tests/monads.scm, tests/nar.scm, tests/packages.scm, tests/pk-crypto.scm, tests/pki.scm, tests/profiles.scm, tests/publish.scm, tests/pypi.scm, tests/records.scm, tests/scripts-build.scm, tests/scripts.scm, tests/services.scm, tests/sets.scm, tests/size.scm, tests/snix.scm, tests/store.scm, tests/substitute.scm, tests/syscalls.scm, tests/system.scm, tests/ui.scm, tests/union.scm, tests/upstream.scm, tests/utils.scm: Don't exit at the end of test groups. * tests/containers.scm: Likewise. Use 'test-skip' instead of exiting with error code 77.
112 lines
4.4 KiB
Scheme
112 lines
4.4 KiB
Scheme
;;; GNU Guix --- Functional package management for GNU
|
||
;;; Copyright © 2015 Ludovic Courtès <ludo@gnu.org>
|
||
;;;
|
||
;;; This file is part of GNU Guix.
|
||
;;;
|
||
;;; GNU Guix is free software; you can redistribute it and/or modify it
|
||
;;; under the terms of the GNU General Public License as published by
|
||
;;; the Free Software Foundation; either version 3 of the License, or (at
|
||
;;; your option) any later version.
|
||
;;;
|
||
;;; GNU Guix is distributed in the hope that it will be useful, but
|
||
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;;; GNU General Public License for more details.
|
||
;;;
|
||
;;; You should have received a copy of the GNU General Public License
|
||
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
|
||
|
||
(define-module (test-challenge)
|
||
#:use-module (guix tests)
|
||
#:use-module (guix hash)
|
||
#:use-module (guix store)
|
||
#:use-module (guix monads)
|
||
#:use-module (guix derivations)
|
||
#:use-module (guix gexp)
|
||
#:use-module (guix scripts challenge)
|
||
#:use-module (guix scripts substitute)
|
||
#:use-module (srfi srfi-1)
|
||
#:use-module (srfi srfi-26)
|
||
#:use-module (srfi srfi-64)
|
||
#:use-module (rnrs bytevectors)
|
||
#:use-module (ice-9 match))
|
||
|
||
(define %store
|
||
(open-connection-for-tests))
|
||
|
||
(define query-path-hash*
|
||
(store-lift query-path-hash))
|
||
|
||
(define-syntax-rule (test-assertm name exp)
|
||
(test-assert name
|
||
(run-with-store %store exp
|
||
#:guile-for-build (%guile-for-build))))
|
||
|
||
(define* (call-with-derivation-narinfo* drv thunk hash)
|
||
(lambda (store)
|
||
(with-derivation-narinfo drv (sha256 => hash)
|
||
(values (run-with-store store (thunk)) store))))
|
||
|
||
(define-syntax with-derivation-narinfo*
|
||
(syntax-rules (sha256 =>)
|
||
((_ drv (sha256 => hash) body ...)
|
||
(call-with-derivation-narinfo* drv
|
||
(lambda () body ...)
|
||
hash))))
|
||
|
||
|
||
(test-begin "challenge")
|
||
|
||
(test-assertm "no discrepancies"
|
||
(let ((text (random-text)))
|
||
(mlet* %store-monad ((drv (gexp->derivation "something"
|
||
#~(call-with-output-file
|
||
#$output
|
||
(lambda (port)
|
||
(display #$text port)))))
|
||
(out -> (derivation->output-path drv)))
|
||
(mbegin %store-monad
|
||
(built-derivations (list drv))
|
||
(mlet %store-monad ((hash (query-path-hash* out)))
|
||
(with-derivation-narinfo* drv (sha256 => hash)
|
||
(>>= (discrepancies (list out) (%test-substitute-urls))
|
||
(lift1 null? %store-monad))))))))
|
||
|
||
(test-assertm "one discrepancy"
|
||
(let ((text (random-text)))
|
||
(mlet* %store-monad ((drv (gexp->derivation "something"
|
||
#~(call-with-output-file
|
||
#$output
|
||
(lambda (port)
|
||
(display #$text port)))))
|
||
(out -> (derivation->output-path drv)))
|
||
(mbegin %store-monad
|
||
(built-derivations (list drv))
|
||
(mlet* %store-monad ((hash (query-path-hash* out))
|
||
(wrong-hash
|
||
-> (let* ((w (bytevector-copy hash))
|
||
(b (bytevector-u8-ref w 0)))
|
||
(bytevector-u8-set! w 0
|
||
(modulo (+ b 1) 128))
|
||
w)))
|
||
(with-derivation-narinfo* drv (sha256 => wrong-hash)
|
||
(>>= (discrepancies (list out) (%test-substitute-urls))
|
||
(match-lambda
|
||
((discrepancy)
|
||
(return
|
||
(and (string=? out (discrepancy-item discrepancy))
|
||
(bytevector=? hash
|
||
(discrepancy-local-sha256
|
||
discrepancy))
|
||
(match (discrepancy-narinfos discrepancy)
|
||
((bad)
|
||
(bytevector=? wrong-hash
|
||
(narinfo-hash->sha256
|
||
(narinfo-hash bad))))))))))))))))
|
||
|
||
(test-end)
|
||
|
||
;;; Local Variables:
|
||
;;; eval: (put 'with-derivation-narinfo* 'scheme-indent-function 2)
|
||
;;; End:
|